1 CALL HROFF:CLS
2 PRINT "For a real random game, you need to"
3 PRINT "enter a different number each time"
4 PRINT "you play.":PRINT
5 INPUT "Please, enter a random number: ";N:RANDOMIZE N
10 CALL HROFF:CLS("BGG")
12 CALL POKE(50500,162,5,45,162,136,45,10):CALL EXEC(50500)
20 DIM CB$(57),CN$(57),CY(57),CM(57),CO(57),CT$(57)
30 DIM CR$(57),CS(57),CV(57),CI(57)
40 DIM DC(56),D1(56),D2(56)
45 CALL CHAR(22,"AA55AA55AA0000000000")
46 CALL CHAR(23,"A050A050A050A050A050")
47 CALL CHAR(24,"A050A050A00000000000")
50 CALL CHAR(25,"FE82828282828282FE00")
60 GOSUB 9900
70 GOSUB 7000
75 CLS("BGG")
200 GOSUB 8800:REM DISTRIBUE LES CARTE
202 TR=1
205 CLS("BGG")
210 GOSUB 9000:REM DESSINE LES CARTES
230 I1=1:I2=1:J1=56:J2=56:JH=0
235 DJY=19:DJX=3:GJY=22:GJX=19:DCY=19:DCX=22:GCY=22:GCX=38
237 GOSUB 7700:REM affiche les mini cartes
240 IF G=2 OR JH=2 THEN GOTO 260
245 X=D1(I1):XC=4:GOSUB 9300
250 GOSUB 8600:REM choix critere joueur
255 REM X=D2(I2):XC=23:GOSUB 9300
257 GOTO 300
260 X=D2(I2):XC=23:GOSUB 9300
270 IF INTRND(4)>DL THEN CR=CI(D2(I2)) ELSE CR=INTRND(7)
280 CALL COLOR("0WR")
281 LOCATE(9+CR,21)
282 PRINT CHR$(11)
290 X=D1(I1):XC=4:GOSUB 9300
300 GOSUB 8000:REM on test quelle carte gagne
310 IF G=1 THEN GOSUB 7800
315 IF G=2 THEN GOSUB 7900
320 I1=I1+1:I2=I2+1
330 CALL COLOR("0BG")
340 LOCATE(DJY,DJX):PRINT" ":DJX=DJX-1
350 IF DJX=2 AND DJY>19 THEN DJX=19:DJY=DJY-1
355 IF DJX=2 AND DJY=19 THEN GOTO 400
360 LOCATE(DCY,DCX):PRINT" ":DCX=DCX-1
370 IF DCX=21 AND DCY>19 THEN DCX=38:DCY=DCY-1
375 IF DCX=21 AND DCY=19 THEN GOTO 400
380 XC=3:GOSUB 9800:XC=22:GOSUB 9800
390 IF D1(I1)=0 OR D1(I2)=0 THEN GOTO 400
394 IF I1=J1 THEN PRINT "GAGNE !!!":END
395 GOTO 240
400 REM --- FIN DU TOUR ---
401 REM reditribution des cartes du joueur
410 CALL HROFF:CLS("BGG"):CALL EXEC(50500)
415 CALL COLOR("0WR")
420 LOCATE(5,14):PRINT "END OF TURN ";TR
425 IF TR=TG THEN GOTO 800
430 TR=TR+1:CALL COLOR("0BG")
450 LOCATE(9,3):PRINT "PLEASE WAIT WHILE CARDS ARE SHUFFLED"
460 CALL COLOR("0BR"):LOCATE(11,6):PRINT "                             "
470 L=6:CALL COLOR("0Bb")
480 J=1
490 FOR I=1 TO 56
500 DC(I)=0
510 IF D1(I)<>0 THEN DC(J)=D1(I):J=J+1
520 D1(I)=0
530 NEXT I
540 J=J-1
545 IF J=0 THEN GOTO 6500
550 FOR I=1 TO J
560 K=INTRND(J):IF D1(K)<>0 THEN GOTO 560
570 D1(K)=DC(I)
580 L=L+.5:LOCATE(11,INT(L)):PRINT " "
590 NEXT I
600 REM reditribution des cartes de l'ordi
610 J=1
620 FOR I=1 TO 56
630 DC(I)=0
640 IF D2(I)<>0 THEN DC(J)=D2(I):J=J+1
650 D2(I)=0
660 NEXT I
670 J=J-1
675 IF J=0 THEN GOTO 6000
680 FOR I=1 TO J
690 K=INTRND(J):IF D2(K)<>0 THEN GOTO 690 
700 D2(K)=DC(I)
710 L=L+.5:LOCATE(11,INT(L)):PRINT " "
720 NEXT I
730 GOTO 205
800 REM --- END OF TURNS ---
805 CALL COLOR("0BG")
810 LOCATE(7,6):PRINT "LET'S SEE WHO HAS MOST CARDS !"
815 CALL COLOR("0BY")
820 LOCATE(9,23):PRINT "COMPUTER HAS"
825 S2=0:X=22:Y=12:CALL COLOR("1WG")
830 FOR I=1 TO 56
840 IF D2(I)=0 THEN GOTO 870
845 PAUSE .3
850 LOCATE(Y,X):PRINT CHR$(25):S2=S2+1
860 X=X+1:IF X=39 THEN X=22:Y=Y+1
870 NEXT I
880 CALL COLOR("0BY")
890 LOCATE(10,25):PRINT STR$(S2);" CARDS"
900 LOCATE(9,6):PRINT "YOU HAVE"
910 S1=0:X=2:Y=12:CALL COLOR("1WG")
920 FOR I=1 TO 56
930 IF D1(I)=0 THEN GOTO 960
935 PAUSE .3
940 LOCATE(Y,X):PRINT CHR$(25):S1=S1+1
950 X=X+1:IF X=19 THEN X=2:Y=Y+1
960 NEXT I
962 CALL COLOR("0BY")
963 LOCATE(10,6):PRINT STR$(S1);" CARDS"
965 LOCATE(18,16):CALL COLOR("0Wb")
970 IF S1>S2 THEN PRINT "YOU WIN !":CALL SPEECH("S,00B8001CFF")
980 IF S1<S2 THEN PRINT "YOU LOSE...":CALL SPEECH("S,00B6FF")
990 IF S1=S2 THEN PRINT "DRAW !":CALL SPEECH("S,00B5FF")
1000 PAUSE
1010 GOTO 70
2000 END
6000 REM --- PLAYER WINS ---
6010 CLS("BYG")
6020 LOCATE(9,11):CALL COLOR("0RHL")
6030 PRINT "YYOOUU  WWIINN  !!"
6040 LOCATE(10,11)
6050 PRINT "YYOOUU  WWIINN  !!"
6060 CALL SPEECH("S,00B8001CFF")
6070 PAUSE
6100 GOTO 7000
6500 REM --- COMPUTER WINS ---
6510 CLS("BYG")
6515 CALL SPEECH("S,002DFF")
6520 LOCATE(9,8):CALL COLOR("0RHL")
6530 PRINT "YYOOUU  LLOOSSEE  ::--(("
6540 LOCATE(10,8)
6550 PRINT "YYOOUU  LLOOSSEE  ::--(("
6560 CALL SPEECH("S,00B6FF")
6570 PAUSE
6590 GOTO 7000
7000 REM --- MENU ---
7010 CLS("BYG")
7015 CALL SPEECH("S,002DFF")
7020 LOCATE(2,8):CALL COLOR("0RHL")
7030 PRINT "88--BBIITT  BBAATTTTLLEE"
7040 LOCATE(3,8)
7050 PRINT "88--BBIITT  BBAATTTTLLEE"
7055 CALL COLOR("0BY")
7060 LOCATE(5,2):PRINT"BEAT THE COMPUTER IN THIS CARD GAME."
7070 PRINT" CHOOSE THE RIGHT CHARACTERISTIC TO"
7080 PRINT" OVER POWER THE OPONNENT'S CARD."
7090 CALL COLOR("0Yb")
7100 PRINT:PRINT " HOW MANY TURNS DO YOU WANT TO PLAY ?"
7105 CALL COLOR("0BY")
7110 PRINT " ENTER 0 TO PLAY UNTIL YOU WIN ALL CARDS"
7120 INPUT TG
7130 IF TG<0 OR TG>20 THEN LOCATE(8,1):GOTO 7090
7140 CALL COLOR("0Yb")
7150 PRINT:PRINT " CHOOSE GAME MODE :"
7160 CALL COLOR("0BY")
7170 PRINT " -1- NORMAL (CHARACTERISTICS DISPLAYED)"
7180 PRINT " -2- BLIND (CHARACTERISTICS HIDDEN)"
7185 PRINT " -3- BLIND EXTREME (PICTURE ONLY)"
7190 INPUT GM
7200 IF GM<1 OR GM>3 THEN LOCATE(12,1):GOTO 7140
7210 CALL COLOR("0Yb")
7220 PRINT:PRINT " CHOOSE EXL-100 A.I. LEVEL :"
7225 CALL COLOR("0BY")
7230 PRINT " 1 = EASY / 2 = MEDIUM / 3 = HARD"
7240 INPUT DL
7250 IF DL<1 OR DL>3 THEN LOCATE(17,1):GOTO 7210
7390 RETURN
7700 REM --- AFFICHE LES MINI CARTES ---
7705 I=1
7710 CALL COLOR("1WG")
7720 LOCATE(DJY,DJX):PRINT CHR$(25)
7730 DJX=DJX+1:I=I+1:IF DJX=20 THEN DJX=3:DJY=DJY+1
7735 IF D1(I)<>0 THEN GOTO 7720
7740 I=1
7750 LOCATE(DCY,DCX):PRINT CHR$(25)
7760 DCX=DCX+1:I=I+1:IF DCX=39 THEN DCX=22:DCY=DCY+1
7762 IF D2(I)<>0 THEN GOTO 7750
7765 DCX=DCX-1:DJX=DJX-1
7770 RETURN
7800 REM --- JOUEUR GAGNE ---
7810 D1(J1)=C2:J1=J1-1:D2(I2)=0
7820 CALL COLOR("1MG")
7825 LOCATE(GJY,GJX):PRINT CHR$(25)
7830 GJX=GJX-1
7835 IF GJX=2 THEN GJX=19:GJY=GJY-1
7840 RETURN
7900 REM ---ORDI GAGNE ---
7910 D2(J2)=C1:J2=J2-1:D1(I1)=0
7920 CALL COLOR("1MG")
7925 LOCATE(GCY,GCX):PRINT CHR$(25)
7930 GCX=GCX-1
7935 IF GCX=21 THEN GCX=38:GCY=GCY-1
7940 RETURN
8000 REM --- TEST QUELLE CARTE GAGNE ---
8001 C1=D1(I1):C2=D2(I2):G=0
8002 X=C1:XC=4
8003 IF GM=3 THEN GOSUB 9305
8004 IF GM>1 THEN GOSUB 9405
8010 IF G<>2 AND JH<>2 THEN X=C2:XC=23:GOSUB 9300
8020 ON CR GOTO 8030,8060,8090,8120,8150,8180,8210
8025 RETURN
8030 IF CY(C1)<CY(C2) THEN G=1 ELSE G=2
8040 IF CY(C1)=CY(C2) THEN G=0
8050 GOTO 8300
8060 IF CM(C1)>CM(C2) THEN G=1 ELSE G=2
8070 IF CM(C1)=CM(C2) THEN G=0
8080 GOTO 8300
8090 IF CO(C1)>CO(C2) THEN G=1 ELSE G=2
8100 IF CO(C1)=CO(C2) THEN G=0
8110 GOTO 8300
8120 P=POS(CT$(C1),"x",1)
8122 V1=VAL(SEG$(CT$(C1),1,P-1))*VAL(SEG$(CT$(C1),P+1,LEN(CT$(C1))-P))
8124 P=POS(CT$(C2),"x",1)
8126 V2=VAL(SEG$(CT$(C2),1,P-1))*VAL(SEG$(CT$(C2),P+1,LEN(CT$(C2))-P))
8130 IF V1>V2 THEN G=1 ELSE G=2
8140 IF V1=V2 THEN G=0
8145 GOTO 8300
8150 P=POS(CR$(C1),"x",1)
8152 V1=VAL(SEG$(CR$(C1),1,P-1))*VAL(SEG$(CR$(C1),P+1,LEN(CR$(C1))-P))
8154 P=POS(CR$(C2),"x",1)
8156 V2=VAL(SEG$(CR$(C2),1,P-1))*VAL(SEG$(CR$(C2),P+1,LEN(CR$(C2))-P))
8160 IF V1>V2 THEN G=1 ELSE G=2
8170 IF V1=V2 THEN G=0
8175 GOTO 8300
8180 IF CS(C1)>CS(C2) THEN G=1 ELSE G=2
8190 IF CS(C1)=CS(C2) THEN G=0
8200 GOTO 8300
8210 IF CV(C1)>CV(C2) THEN G=1 ELSE G=2
8220 IF CV(C1)=CV(C2) THEN G=0
8230 GOTO 8300
8300 IF G=1 THEN CALL COLOR("0Wb"):LOCATE(1,6):PRINT"PLAYER WINS":JH=1
8305 IF G=1 THEN CALL SPEECH("S,00B8001CFF")
8310 IF G=2 THEN CALL COLOR("0WR"):LOCATE(1,24):PRINT"COMPUTER WINS":JH=2
8315 IF G=2 THEN CALL SPEECH("S,00B6FF")
8320 IF G=0 THEN CALL COLOR("0BG"):LOCATE(1,19):PRINT"DRAW"
8325 IF G=0 THEN CALL SPEECH("S,00B5FF")
8330 X=C1:XC=4
8332 IF GM=3 THEN GOSUB 9305
8334 GOSUB 9405
8340 X=C2:XC=23:GOSUB 9405
8350 A$=KEY$
8360 CALL COLOR("0BG"):LOCATE(1,4):PRINT"                                  "
8390 RETURN
8600 REM --- CHOIX CARACTERISTIQUE ---
8610 Y=10
8620 CALL COLOR("0WR"):LOCATE(Y,2):PRINT CHR$(11)
8630 A$=KEY$
8632 IF ASC(A$)=32 THEN GOTO 8700
8635 CALL COLOR("0BG"):LOCATE(Y,2):PRINT " "
8640 IF ASC(A$)=130 THEN Y=Y+1
8650 IF ASC(A$)=128 THEN Y=Y-1
8660 IF Y=9 THEN Y=16
8670 IF Y=17 THEN Y=10
8690 GOTO 8620
8700 CR=Y-9
8710 RETURN
8800 REM --- DISTRIBUE LES CARTES ---
8805 T=1:ID=56:I1=1:I2=1
8807 LOCATE(9,3):PRINT "PLEASE WAIT WHILE CARDS ARE SHUFFLED"
8808 CALL COLOR("0BR"):LOCATE(11,6):PRINT "                             "
8809 K=6:CALL COLOR("0Bb")
8810 FOR I=1 TO 56:DC(I)=I:NEXT I
8812 FOR I=1 TO 56
8820 C=INT(RND*ID)+1:D=DC(C)
8830 IF T=1 THEN T=2:GOTO 8850
8840 D1(I1)=D:I1=I1+1:T=1:GOTO 8855
8850 D2(I2)=D:I2=I2+1
8855 DC(C)=0:ID=ID-1
8860 FOR J=C TO ID
8870 DC(J)=DC(J+1):DC(J+1)=0
8880 NEXT J
8882 K=K+.5:LOCATE(11,INT(K)):PRINT " "
8885 NEXT I
8890 RETURN
9000 REM --- DESSINNE CARTES ---
9020 CALL HRON("G",6,4)
9030 FOR I=0 TO 40
9040 CALL LINE("W",16,I,151,I)
9050 CALL LINE("W",168,I,303,I)
9051 IF I/2=INT(I/2) THEN K=0 ELSE K=1
9052 CALL PLOT("B",152+K,I):CALL PLOT("B",154+K,I)
9054 CALL PLOT("B",304+K,I):CALL PLOT("B",306+K,I)
9060 NEXT I
9062 CALL COLOR("1BG")
9064 FOR I=3 TO 17:LOCATE(I,20):PRINT CHR$(23)
9065 LOCATE(I,39):PRINT CHR$(23):NEXT I
9066 FOR I=0 TO 15:LOCATE(18,4+I):PRINT CHR$(22)
9068 LOCATE(18,23+I):PRINT CHR$(22):NEXT I
9070 LOCATE(18,20):PRINT CHR$(24)
9072 LOCATE(18,39):PRINT CHR$(24)
9075 CALL COLOR("0BW")
9080 XC=3:GOSUB 9800
9090 XC=22:GOSUB 9800
9150 RETURN
9300 REM --- AFFICHE CARTE ORDI ---
9302 IF GM=3 AND XC=4 THEN GOTO 9321
9305 CALL COLOR("0BY")
9310 LOCATE(3,XC+(14-LEN(CB$(X)))/2):PRINT CB$(X)
9315 LOCATE(4,XC+(14-LEN(CN$(X)))/2):PRINT CN$(X)
9320 IF GM=3 AND XC=4 THEN RETURN
9321 IF XC=4 THEN XX=83 ELSE XX=235
9322 ON INT(X/10)+1 GOTO 9323,9325,9327,9330,9332,9334
9323 ON X GOSUB 11000,11100,11200,11300,11400,11500,11600,11700,11800
9324 GOTO 9335
9325 ON X-9 GOSUB 11900,12000,12100,12200,12300,12400,12500,12600,12700,12800
9326 GOTO 9335
9327 ON X-19 GOSUB 12900,13000,13100,13200,13300,13400,13500,13600,13700,13800
9328 GOTO 9335
9330 ON X-29 GOSUB 13900,14000,14100,14200,14300,14400,14500,14600,14700,14800
9331 GOTO 9335
9332 ON X-39 GOSUB 14900,15000,15100,15200,15300,15400,15500,15600,15700,15800
9333 GOTO 9335
9334 ON X-49 GOSUB 15900,16000,16100,16200,16300,16400,16500
9335 CALL COLOR("0BW")
9337 LOCATE(10,XC):PRINT "YEAR  :"
9340 LOCATE(11,XC):PRINT "RAM   :"
9350 LOCATE(12,XC):PRINT "COLORS:"
9360 LOCATE(13,XC):PRINT "TEXT  : "
9370 LOCATE(14,XC):PRINT "PIXELS: "
9380 LOCATE(15,XC):PRINT "SPEED :"
9390 LOCATE(16,XC):PRINT "VOICES:"
9400 IF GM>1 AND XC=4 THEN GOTO 9490
9405 CALL COLOR("0BW")
9410 LOCATE(10,XC+7):PRINT CY(X)
9420 LOCATE(11,XC+7):PRINT CM(X);" Kb"
9430 LOCATE(12,XC+7):IF CO(X)=0 THEN PRINT " None" ELSE PRINT CO(X)
9440 LOCATE(13,XC+8):IF CT$(X)="0x0" THEN PRINT "None" ELSE PRINT CT$(X)
9450 LOCATE(14,XC+8):IF CR$(X)="0x0" THEN PRINT "None" ELSE PRINT CR$(X)
9460 LOCATE(15,XC+7):PRINT CS(X);" MHz"
9470 LOCATE(16,XC+7):IF CV(X)=0 THEN PRINT " None" ELSE PRINT CV(X)
9490 RETURN
9800 REM --- EFFACE CARTE
9810 FOR I=2 TO 17
9820 LOCATE(I,XC)
9825 IF I<6 THEN CALL COLOR("0BY") ELSE CALL COLOR("0BW")
9830 PRINT "                 "
9832 CALL COLOR("0BG")
9833 LOCATE(I,2):PRINT " "
9834 LOCATE(I,21):PRINT " "
9840 NEXT I
9850 IF XC=3 THEN XX=43 ELSE XX=192
9860 CALL RECT(XX,80,85,40,"W")
9890 RETURN
9900 REM --- LECTURE DONNEES COMPS ---
9910 I=1
9920 RESTORE 10000
9930 READ BR$
9940 IF BR$="X" THEN GOTO 9980 ELSE CB$(I)=BR$
9950 READ CN$(I),CY(I),CM(I),CO(I),CT$(I),CR$(I),CS(I),CV(I),CI(I)
9960 I=I+1
9970 GOTO 9930
9980 RETURN
10000 DATA SINCLAIR,"ZX SPECTRUM",1982,48,15,32x24,256x192,3.5,1,4
10010 DATA SINCLAIR,"ZX-81",1981,1,2,24x32,64x48,3.2,1,1
10020 DATA SINCLAIR,QL,1986,128,8,85x25,512x256,7.5,1,5
10030 DATA "BIT CORPORATION","BIT 90",1983,18,16,32x24,256x192,3.6,3,3
10035 DATA "BIT CORPORATION","BIT 60",1983,2,128,26x24,156x192,1.2,2,3
10040 DATA "IBM","5100",1975,64,2,64x16,0x0,1.9,0,1
10050 DATA IBM,PC,1981,64,16,80x25,640x200,4.8,1,6
10060 DATA IBM,"PC AT",1984,512,64,80x43,640x350,8,1,5
10070 DATA IBM,"PC XT",1983,128,16,80x25,640x200,4.8,1,5
10080 DATA EPSON,"QX 10",1983,256,2,80x24,640x400,4,1,5
10090 DATA EPSON,"HX 20",1982,16,2,20x4,120x32,0.6,2,7
10100 DATA TANGERINE,"ORIC 1",1982,48,8,40x28,240x200,1,3,7
10110 DATA COMMODORE,C64,1982,64,16,40x25,320x200,1,3,2
10120 DATA COMMODORE,"VIC 20",1980,5,16,23x22,184x176,1.1,3,2
10130 DATA COMMODORE,"PET 2001",1977,4,2,40x25,0x0,1,0,1
10140 DATA COMMODORE,C16,1984,16,121,40x25,320x200,1.1,2,3
10150 DATA COMMODORE,"AMIGA 500",1987,512,4096,80x25,704x484,7.1,4,3
10160 DATA AMSTRAD,"CPC 464",1984,64,27,80x25,640x200,4,3,5
10170 DATA AMSTRAD,"CPC 6128",1985,128,27,80x25,640x200,4,3,2
10180 DATA R2E,MICRAL,1973,2,0,0x0,0x0,0.5,0,1
10190 DATA APPLE,"APPLE II",1977,64,16,40x24,280x192,1,1,1
10200 DATA TANDY,"TRS-80 Model 1",1977,4,2,64x16,128x48,1.8,1,1
10210 DATA SHARP,MZ-80K,1978,20,2,40x25,80x50,2,1,1
10220 DATA ACORN,BBC,1981,32,8,80x32,640x256,2,4,5
10240 DATA TEXAS-INSTRUMENT,"TI-99/4A",1981,16,32,40x24,256x192,3,3,7
10250 DATA ATARI,800,1979,48,256,40x25,320x192,1.8,4,3
10260 DATA ATARI,400,1979,8,256,40x25,320x192,1.8,4,3
10270 DATA NEC,PC-8001,1979,16,8,80x25,160x100,4,1,1
10280 DATA OSBORNE,"OSBORNE 1",1981,64,2,104x24,0x0,4,1,2
10290 DATA THOMSON,"TO-7",1982,8,8,40x25,320x200,1,1,5
10300 DATA ACORN,ELECTRON,1983,32,16,80x32,640x256,1,1,5
10310 DATA MATRA,ALICE,1983,4,9,32x16,128x64,0.89,1,3
10320 DATA MSX,MSX1,1983,64,16,40x24,256x192,3.6,3,2
10330 DATA APPLE,LISA,1983,1000,2,80x25,720x364,5,1,2
10340 DATA NEC,PC-9800,1982,128,8,80x24,640x400,5,1,5
10350 DATA APPLE,MACINTOSH,1984,128,2,40x32,512x342,7.8,4,5
10360 DATA THOMSON,MO5,1984,32,16,40x25,320x240,1,1,3
10370 DATA TANDY,"TANDY 1000",1984,128,16,80x25,640x200,4.8,3,5
10380 DATA ATARI,520ST,1985,512,512,80x25,640x400,8,3,2
10390 DATA EXELVISION,EXL-100,1984,34,8,40x24,320x250,4.9,1,5
10400 DATA PHILIPS,VG-5000,1984,24,8,40x25,0x0,4,1,2
10410 DATA MITS,ALTAIR,1975,4,0,0x0,0x0,2,0,1
10420 DATA COMPUCOLOR,"COMPUCOLOR II",1977,32,8,64x32,128x128,1.9,0,1
10430 DATA EXIDY,SORCERER,1978,4,2,64x30,0x0,2.1,0,1
10440 DATA DAI,DAI,1980,48,16,60x24,528x240,2,3,5
10450 DATA GRUNDY,NEWBRAIN,1982,32,2,80x30,640x256,4,0,5
10460 DATA "DRAGON DATA","DRAGON 32",1982,32,9,32x16,256x192,0.9,1,2
10470 DATA ENTERPRISE,64,1985,64,256,84x64,672x512,4,3,3
10480 DATA VTECH,"LASER 200",1983,2,8,32x16,128x64,3.6,1,6
10490 DATA INTERACT,COMPUTER,1979,16,8,17x12,112x78,2,1,1
10500 DATA TOMY,TUTOR,1983,16,16,32x24,256x192,2.7,3,4
10510 DATA CAMPUTERS,LYNX,1983,128,8,40x24,256x248,6,1,2
10520 DATA SANYO,PHC-25,1983,16,8,32x16,256x192,4,0,5
10530 DATA SHARP,MZ-700,1982,64,8,40x25,80x50,3.5,1,2
10540 DATA APPLE,IIGS,1986,256,4096,80x25,640x200,2.8,32,7
10550 DATA "APOLLO 7",SQUALE,1985,92,16,40x25,256x256,1,3,2
10600 DATA X,X,0,0,0,X,X,0,0,0
11000 REM --- ZX SPECTRUM ---
11010 L=43:H=29:XX=XX-(L/2):YY=100-(H/2)
11020 CALL RECT(XX,YY,43,29,"B")
11030 CALL LINE("R",XX+35,YY+28,XX+42,YY+21)
11040 CALL LINE("Y",XX+36,YY+28,XX+42,YY+22)
11050 CALL LINE("G",XX+37,YY+28,XX+42,YY+23)
11060 CALL LINE("B",XX+38,YY+28,XX+42,YY+24)
11070 CALL LINE("W",XX,YY+6,XX+42,YY+6)
11090 CALL KYB1(XX+3,YY+11,4,9,1,4,"W")
11095 RETURN
11100 REM --- ZX-81 ---
11110 L=26:H=30:XX=XX-(L/2):YY=100-(H/2)
11120 CALL RECT(XX,YY,L,H,"B")
11130 CALL KYB1(XX+2,YY+17,4,7,0,3,"W")
11140 CALL LINE("W",XX,YY+14,XX+25,YY+14)
11150 CALL LINE("R",XX+1,YY+10,XX+2,YY+10):CALL LINE("R",XX+1,YY+12,XX+2,YY+12)
11160 CALL LINE("R",XX+4,YY+10,XX+6,YY+12):CALL LINE("R",XX+4,YY+12,XX+6,YY+10)
11170 CALL LINE("R",XX+8,YY+10,XX+10,YY+10)
11175 CALL LINE("R",XX+10,YY+10,XX+10,YY+12)
11180 CALL LINE("R",XX+10,YY+12,XX+8,YY+12)
11185 CALL LINE("R",XX+8,YY+12,XX+8,YY+10)
11190 CALL LINE("R",XX+12,YY+10,XX+12,YY+12)
11195 RETURN
11200 REM --- SINCLAIR QL ---
11210 L=73:H=23:XX=XX-(L/2):YY=100-(H/2)
11220 CALL RECT(XX,YY,L,H,"B")
11230 CALL KYB1(XX+7,YY+6,4,10,1,4,"W")
11240 CALL LINE("W",XX+52,YY+2,XX+52,YY+19)
11250 CALL LINE("B",XX+73,YY+2,XX+73,YY+19)
11260 FOR I=1 TO 4:CALL LINE("W",XX+2,YY+2+(I*4),XX+3,YY+2+(I*4))
11270 CALL LINE("W",XX+2,YY+3+(I*4),XX+3,YY+3+(I*4)):NEXT I
11280 FOR I=54 TO 70 STEP 2:CALL PLOT("B",XX+I,YY-1):NEXT I
11290 RETURN
11300 REM --- BIT 90 ---
11310 L=48:H=27:XX=XX-(L/2):YY=100-(H/2)
11320 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+10,44,15,"B")
11330 CALL KYB1(XX+5,YY+12,4,10,1,3,"G")
11340 CALL RECT(XX+38,YY+18,2,2,"G"):CALL RECT(XX+42,YY+18,2,2,"G")
11350 CALL RECT(XX+40,YY+15,2,2,"G"):CALL RECT(XX+40,YY+21,2,2,"G")
11360 FOR I=36 TO 44 STEP 2:CALL PLOT("B",XX+I,YY+1):NEXT I
11390 RETURN
11400 REM --- BIT 60 ---
11410 L=43:H=23:XX=XX-(L/2):YY=100-(H/2)
11420 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+1,YY+5,41,15,"B")
11430 CALL KYB1(XX+4,YY+7,4,11,1,3,"W")
11440 CALL RECT(XX+3,YY+2,8,2,"B")
11490 RETURN
11500 REM --- IBM 5100 ---
11510 L=26:H=30:XX=XX-(L/2):YY=100-(H/2)
11520 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX,YY+20,26,10,"w")
11530 CALL RECT(XX+2,YY+22,17,6,"w"):CALL RECT(XX+20,YY+22,4,6,"w")
11540 FOR I=4 TO 16 STEP 2:CALL PLOT("B",XX+1,YY+I):NEXT I
11590 RETURN
11600 REM --- IBM 5150 ---
11610 L=36:H=30:XX=XX-(L/2):YY=100-(H/2)
11620 CALL RECT(XX,YY+18,36,11,"w"):CALL RECT(XX+13,YY+20,21,7,"B")
11630 CALL RECT(XX+5,YY+1,25,18,"w"):CALL RECT(XX+7,YY+3,21,14,"B")
11640 CALL RECT(XX+8,YY+4,16,12,"G")
11650 CALL RECT(XX+25,YY+11,2,2,"W"):CALL RECT(XX+25,YY+14,2,2,"W")
11660 CALL RECT(XX+17,YY+22,2,3,"W"):CALL RECT(XX+28,YY+22,2,3,"W")
11670 CALL LINE("W",XX+15,YY+23,XX+20,YY+23)
11680 CALL LINE("W",XX+26,YY+23,XX+31,YY+23)
11685 CALL LINE("W",XX+23,YY+21,XX+23,YY+25)
11687 CALL LINE("W",XX+25,YY+4,XX+26,YY+5)
11690 FOR I=2 TO 10 STEP 2:CALL LINE("B",XX+I,YY+24,XX+I,YY+26)
11692 NEXT I
11695 RETURN
11700 REM --- IBM PC AT ---
11710 L=36:H=31:XX=XX-(L/2):YY=100-(H/2)
11720 CALL RECT(XX,YY+17,36,13,"w"):CALL RECT(XX+2,YY+20,2,2,"B")
11722 CALL RECT(XX+6,YY+20,7,2,"B")
11724 CALL RECT(XX+24,YY+19,10,4,"B"):CALL RECT(XX+24,YY+24,10,4,"B")
11730 CALL RECT(XX+5,YY,25,18,"w"):CALL RECT(XX+7,YY+2,21,14,"B")
11740 CALL RECT(XX+8,YY+3,16,12,"C"):CALL RECT(XX+25,YY+7,2,2,"W")
11750 CALL RECT(XX+25,YY+10,2,2,"W"):CALL RECT(XX+25,YY+13,2,2,"W")
11755 CALL LINE("W",XX+25,YY+3,XX+26,YY+4)
11760 FOR I=2 TO 18 STEP 2:CALL LINE("B",XX+I,YY+24,XX+I,YY+28)
11770 NEXT
11795 RETURN
11800 REM --- IBM PC XT ---
11810 L=36:H=30:XX=XX-(L/2):YY=100-(H/2)
11820 CALL RECT(XX,YY+18,36,11,"w"):CALL RECT(XX+13,YY+20,21,7,"B")
11830 CALL RECT(XX+5,YY+1,25,18,"w"):CALL RECT(XX+7,YY+3,21,14,"B")
11840 CALL RECT(XX+8,YY+4,16,12,"C"):CALL RECT(XX+25,YY+8,2,2,"W")
11850 CALL RECT(XX+25,YY+11,2,2,"W"):CALL RECT(XX+25,YY+14,2,2,"W")
11860 CALL RECT(XX+17,YY+22,2,3,"W"):CALL PLOT("R",XX+26,YY+24)
11870 CALL LINE("W",XX+15,YY+23,XX+20,YY+23)
11880 CALL LINE("W",XX+23,YY+21,XX+23,YY+25)
11885 CALL LINE("W",XX+25,YY+4,XX+26,YY+5)
11890 FOR I=2 TO 10 STEP 2:CALL LINE("B",XX+I,YY+24,XX+I,YY+26)
11892 NEXT
11895 RETURN
11900 REM --- EPSON QX10 ---
11910 L=34:H=27:XX=XX-(L/2):YY=100-(H/2)
11920 CALL RECT(XX,YY+19,34,8,"w"):CALL RECT(XX+7,YY+21,20,3,"B")
11930 CALL LINE("W",XX+9,YY+22,XX+14,YY+22)
11940 CALL LINE("W",XX+19,YY+22,XX+24,YY+22)
11945 CALL LINE("B",XX+3,YY+21,XX+3,YY+23)
11950 CALL LINE("B",XX+5,YY+21,XX+5,YY+23)
11955 CALL LINE("B",XX+28,YY+22,XX+28,YY+23)
11960 CALL LINE("B",XX+30,YY+22,XX+30,YY+23)
11970 CALL RECT(XX+6,YY,22,18,"w"):CALL RECT(XX+8,YY+2,18,14,"w")
11980 CALL RECT(XX+9,YY+3,16,12,"G")
11990 RETURN
12000 REM --- EPSON HX-20 ---
12010 L=27:H=19:XX=XX-(L/2):YY=100-(H/2)
12015 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+4,6,2,"B")
12020 CALL RECT(XX+10,YY+2,9,4,"G"):CALL RECT(XX+20,YY+3,5,3,"w")
12030 CALL PLOT("B",XX+22,YY+4):CALL RECT(XX+3,YY+9,21,7,"B")
12040 CALL RECT(XX+21,YY+12,3,2,"R")
12045 CALL LINE("B",XX+1,YY+7,XX+25,YY+7)
12050 CALL LINE("B",XX+7,YY+16,XX+19,YY+16)
12090 RETURN
12100 REM --- ORIC 1 ---
12110 L=46:H=29:XX=XX-(L/2):YY=100-(H/2)
12120 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+1,YY+8,44,18,"B")
12130 CALL KYB1(XX+4,YY+10,4,9,1,4,"W")
12140 CALL RECT(XX+1,YY+5,44,2,"C"):CALL RECT(XX+38,YY+2,6,2,"B")
12190 RETURN
12200 REM --- C64 ---
12210 L=57:H=25:XX=XX-(L/2):YY=100-(H/2)
12220 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+4,YY+9,42,11,"B")
12230 CALL RECT(XX+13,YY+20,23,2,"B")
12240 CALL RECT(XX+49,YY+9,4,11,"B"):CALL RECT(XX,YY+3,57,3,"w")
12250 CALL LINE("B",XX+4,YY+4,XX+15,YY+4):CALL PLOT("R",XX+53,YY+4)
12290 RETURN
12300 REM --- VIC20 ---
12310 L=57:H=25:XX=XX-(L/2):YY=100-(H/2)
12320 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+4,YY+9,42,11,"B")
12330 CALL RECT(XX+13,YY+20,23,2,"B")
12340 CALL RECT(XX+49,YY+9,4,11,"Y"):CALL RECT(XX,YY+3,57,3,"w")
12350 CALL LINE("B",XX+4,YY+4,XX+15,YY+4):CALL PLOT("R",XX+53,YY+4)
12390 RETURN
12400 REM --- PET2001 ---
12410 L=35:H=27:XX=XX-(L/2):YY=100-(H/2)
12415 CALL RECT(XX+10,YY,15,14,"B"):CALL RECT(XX+12,YY+2,11,9,"G")
12420 CALL LINE("B",XX+9,YY+5,XX+9,YY+12)
12422 CALL LINE("B",XX+8,YY+9,XX+8,YY+12)
12426 CALL LINE("B",XX+25,YY+5,XX+25,YY+12)
12428 CALL LINE("B",XX+26,YY+9,XX+26,YY+12)
12429 CALL RECT(XX+4,YY+14,27,4,"w"):CALL RECT(XX+4,YY+15,27,2,"C")
12430 CALL LINE("B",XX+4,YY+14,XX,YY+23)
12432 CALL LINE("B",XX+30,YY+14,XX+34,YY+23)
12436 CALL PLOT("B",XX,YY+24):CALL PLOT("B",XX+34,YY+24)
12438 CALL LINE("B",XX,YY+25,XX+34,YY+25)
12440 CALL LINE("B",XX+2,YY+26,XX+31,YY+26)
12445 CALL RECT(XX+4,YY+19,7,5,"w"):CALL RECT(XX+13,YY+19,12,4,"B")
12450 CALL RECT(XX+26,YY+19,4,4,"B"):CALL PLOT("B",XX+6,YY+21)
12455 CALL PLOT("B",XX+8,YY+21)
12490 RETURN
12500 REM --- C16 ---
12510 L=57:H=25:XX=XX-(L/2):YY=100-(H/2)
12520 CALL RECT(XX,YY,L,H,"B"):CALL RECT(XX+4,YY+9,42,11,"W")
12530 CALL RECT(XX+13,YY+20,23,2,"W")
12540 CALL RECT(XX+49,YY+9,4,11,"W")
12542 CALL LINE("W",XX+1,YY+2,XX+55,YY+2):CALL LINE("W",XX+1,YY+4,XX+55,YY+4)
12550 CALL LINE("W",XX+4,YY+3,XX+15,YY+3):CALL PLOT("R",XX+53,YY+3)
12560 CALL LINE("B",XX+49,YY+11,XX+52,YY+11)
12565 CALL LINE("B",XX+49,YY+14,XX+52,YY+14)
12570 CALL LINE("B",XX+49,YY+17,XX+52,YY+17):CALL PLOT("B",XX+11,YY+3)
12580 CALL PLOT("G",XX+12,YY+3):CALL PLOT("Y",XX+13,YY+3)
12585 CALL PLOT("R",XX+14,YY+3)
12590 RETURN
12600 REM --- AMIGA 500 ---
12610 L=43:H=26:XX=XX-(L/2):YY=100-(H/2)
12620 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+12,27,11,"w")
12630 CALL RECT(XX+34,YY+12,6,11,"w"):CALL RECT(XX+30,YY+12,3,3,"w")
12640 CALL RECT(XX+30,YY+19,3,2,"w"):CALL PLOT("B",XX+31,YY+18)
12650 CALL PLOT("R",XX+40,YY+9):CALL PLOT("G",XX+40,YY+10)
12660 FOR I=3 TO 7 STEP 2:CALL LINE("B",XX,YY+I,XX+41,YY+I):NEXT I
12670 FOR I=2 TO 40 STEP 2:CALL PLOT("B",XX+I,YY+1):NEXT I
12690 RETURN
12700 REM --- AMSTRAD CPC-464 ---
12710 L=60:H=19:XX=XX-(L/2):YY=100-(H/2)
12720 CALL RECT(XX,YY,L,H,"B"):CALL RECT(XX+3,YY+6,32,9,"W")
12730 CALL RECT(XX+9,YY+14,18,3,"W"):CALL RECT(XX+4,YY+7,30,7,"B")
12740 CALL RECT(XX+10,YY+14,16,2,"B"):CALL RECT(XX+37,YY+9,6,8,"W")
12745 CALL RECT(XX+38,YY+10,4,6,"B"):CALL RECT(XX+46,YY+4,11,8,"W")
12750 CALL RECT(XX+47,YY+5,9,6,"B"):CALL RECT(XX+46,YY+13,11,4,"W")
12755 CALL RECT(XX+47,YY+14,9,2,"B"):CALL RECT(XX+39,YY+1,2,2,"W")
12757 CALL RECT(XX+41,YY+3,2,2,"W"):CALL RECT(XX+39,YY+5,2,2,"W")
12758 CALL RECT(XX+37,YY+3,2,2,"W"):CALL RECT(XX+48,YY+6,2,2,"W")
12759 CALL RECT(XX+53,YY+6,2,2,"W"):CALL RECT(XX+39,YY+3,2,2,"G")
12760 CALL RECT(XX+47,YY+14,2,2,"R"):CALL RECT(XX+40,YY+14,2,2,"B")
12762 CALL RECT(XX+24,YY+14,2,2,"G"):CALL RECT(XX+31,YY+12,3,2,"G")
12764 CALL RECT(XX+31,YY+9,3,3,"b"):CALL RECT(XX+32,YY+7,2,2,"G")
12766 CALL RECT(XX+4,YY+7,2,2,"R"):CALL RECT(XX+4,YY+9,2,3,"G")
12768 CALL RECT(XX+4,YY+12,3,2,"G"):CALL PLOT("R",XX+33,YY+3)
12770 CALL LINE("W",XX+3,YY+3,XX+8,YY+3)
12795 RETURN
12800 REM --- AMSTRAD CPC-6128 ---
12810 L=60:H=20:XX=XX-(L/2):YY=100-(H/2)
12820 CALL RECT(XX,YY,L,H,"B"):CALL RECT(XX+2,YY+6,40,12,"W")
12830 CALL LINE("W",XX,YY+3,XX+46,YY+3)
12840 CALL LINE("W",XX+46,YY+3,XX+46,YY+19)
12850 CALL LINE("W",XX+51,YY+3,XX+58,YY+3)
12855 CALL LINE("R",XX+48,YY+5,XX+58,YY+5)
12860 CALL LINE("G",XX+48,YY+10,XX+58,YY+10)
12865 CALL LINE("b",XX+48,YY+18,XX+58,YY+18)
12870 CALL RECT(XX+48,YY+12,11,4,"W"):CALL RECT(XX+49,YY+13,9,2,"B")
12875 CALL PLOT("R",XX+40,YY+1):CALL PLOT("G",XX+41,YY+1)
12890 CALL PLOT("b",XX+42,YY+1)
12895 RETURN
12900 REM ---- R2E MICRAL ---
12910 L=59:H=22:XX=XX-(L/2):YY=100-(H/2)
12920 CALL RECT(XX,YY,L,H,"w")
12925 FOR I=0 TO 6 STEP 2:CALL PLOT("R",XX+27+I,YY+7)
12927 CALL PLOT("R",XX+37+I,YY+7)
12930 CALL PLOT("R",XX+47+I,YY+7):CALL PLOT("R",XX+37+I,YY+13)
12935 CALL PLOT("R",XX+47+I,YY+13):CALL PLOT("R",XX+27+I,YY+16)
12940 CALL PLOT("B",XX+27+I,YY+10):CALL PLOT("B",XX+37+I,YY+10)
12945 CALL PLOT("B",XX+47+I,YY+10):CALL PLOT("B",XX+37+I,YY+16)
12950 CALL PLOT("B",XX+47+I,YY+16):NEXT I
12955 FOR I=0 TO 10 STEP 2:CALL PLOT("R",XX+5+I,YY+13)
12960 CALL PLOT("B",XX+5+I,YY+16):NEXT I
12962 CALL PLOT("B",XX+17,YY+16):CALL PLOT("Y",XX+19,YY+16)
12964 CALL PLOT("B",XX+25,YY+16)
12966 FOR I=0 TO 2 STEP 2:CALL PLOT("R",XX+21+I,YY+7)
12968 CALL PLOT("B",XX+21+I,YY+10):CALL PLOT("R",XX+21+I,YY+16)
12970 NEXT I
12972 FOR I=0 TO 8 STEP 2:CALL PLOT("B",XX+4+I,YY+5)
12973 CALL PLOT("B",XX+4+I,YY+6):NEXT I
12974 CALL LINE("B",XX+12,YY+4,XX+13,YY+4)
12976 CALL LINE("R",XX+14,YY+4,XX+13,YY+5)
12978 CALL LINE("R",XX+13,YY+6,XX+14,YY+6)
12980 CALL LINE("B",XX+14,YY+7,XX+15,YY+7)
12982 CALL PLOT("B",XX+15,YY+6)
12999 RETURN
13000 REM --- APPLE II ---
13010 L=25:H=31:XX=XX-(L/2):YY=100-(H/2)
13020 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+8,YY+13,9,3,"B")
13030 CALL RECT(XX+3,YY+21,19,6,"B")
13035 CALL LINE("B",XX+7,YY+27,XX+17,YY+27) 
13040 CALL LINE("G",XX+9,YY+13,XX+10,YY+13)
13045 CALL LINE("R",XX+9,YY+14,XX+10,YY+14)
13050 CALL LINE("b",XX+9,YY+15,XX+10,YY+15)
13060 CALL PLOT("W",XX+12,YY+14):CALL PLOT("W",XX+14,YY+14)
13065 CALL LINE("B",XX+1,YY+17,XX+23,YY+17)
13070 FOR I=0 TO 10 STEP 2:CALL PLOT("B",XX+1,YY+2+I)
13075 CALL PLOT("B",XX+23,YY+2+I):NEXT I
13090 RETURN
13100 REM --- TRS80 Model 1 ---
13110 L=39:H=17:XX=XX-(L/2):YY=100-(H/2)
13120 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+5,35,10,"B")
13125 CALL RECT(XX+4,YY+6,23,7,"W"):CALL RECT(XX+5,YY+7,21,5,"B")
13130 CALL RECT(XX+30,YY+6,6,8,"W"):CALL RECT(XX+31,YY+7,4,2,"B")
13140 CALL RECT(XX+31,YY+11,4,2,"B"):CALL PLOT("R",XX+28,YY+13)
13145 CALL LINE("B",XX+10,YY+12,XX+20,YY+12)
13150 CALL LINE("W",XX+9,YY+13,XX+21,YY+13)
13160 FOR I=0 TO 20 STEP 2:CALL PLOT("B",XX+9+I,YY+1)
13170 NEXT I
13190 RETURN
13200 REM --- Sharp MZ80K ---
13210 L=31:H=31:XX=XX-(L/2):YY=100-(H/2)
13220 CALL RECT(XX,YY+18,31,13,"w"):CALL RECT(XX+19,YY+12,12,7,"w")
13225 CALL RECT(XX,YY,20,19,"B"):CALL RECT(XX+2,YY+2,16,14,"x")
13230 CALL RECT(XX+21,YY+13,8,2,"B"):CALL RECT(XX+24,YY+21,5,7,"w")
13235 CALL RECT(XX+2,YY+21,15,6,"B"):CALL RECT(XX+17,YY+21,6,7,"b")
13240 CALL LINE("Y",XX+2,YY+27,XX+16,YY+27)
13245 CALL PLOT("R",XX+26,YY+23):CALL PLOT("G",XX+26,YY+25)
13290 RETURN
13300 REM --- ACORN BBC ---
13310 L=37:H=27:XX=XX-(L/2):YY=100-(H/2)
13320 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+12,33,13,"B")
13325 CALL RECT(XX+6,YY+15,26,7,"x"):CALL RECT(XX+12,YY+21,14,3,"x")
13330 CALL LINE("R",XX+11,YY+14,XX+26,YY+14)
13335 CALL PLOT("R",XX+6,YY+23):CALL PLOT("R",XX+8,YY+23)
13340 CALL PLOT("R",XX+10,YY+23)
13390 RETURN
13400 REM --- TI-994A ---
13410 L=34:H=23:XX=XX-(L/2):YY=100-(H/2)
13420 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+12,21,9,"B")
13425 CALL RECT(XX+24,YY+9,8,12,"B"):CALL PLOT("R",XX+21,YY+13)
13430 CALL LINE("B",XX+1,YY+8,XX+32,YY+8)
13435 CALL LINE("B",XX+24,YY+2,XX+31,YY+2)
13440 CALL LINE("B",XX+24,YY+4,XX+31,YY+4)
13445 CALL LINE("B",XX+24,YY+6,XX+31,YY+6)
13490 RETURN
13500 REM --- ATARI 800 ---
13510 L=31:H=27:XX=XX-(L/2):YY=100-(H/2)
13520 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+5,YY,21,11,"w")
13525 CALL RECT(XX+4,YY+15,21,8,"B"):CALL RECT(XX+26,YY+15,2,8,"Y")
13530 CALL LINE("B",XX+1,YY+14,XX+4,YY+11)
13535 CALL LINE("B",XX+26,YY+11,XX+29,YY+14)
13540 CALL LINE("B",XX+5,YY+13,XX+6,YY+12)
13545 CALL PLOT("B",XX+7,YY+13)
13550 CALL LINE("R",XX+26,YY+23,XX+27,YY+23)
13555 CALL LINE("B",XX+8,YY+23,XX+20,YY+23)
13590 RETURN
13600 REM --- ATARI 400 ---
13610 L=27:H=24:XX=XX-(L/2):YY=100-(H/2)
13620 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+5,YY,17,11,"w")
13625 CALL RECT(XX+3,YY+13,19,9,"B"):CALL RECT(XX+23,YY+13,2,8,"Y")
13630 CALL LINE("B",XX+8,YY+7,XX+9,YY+6):CALL PLOT("B",XX+10,YY+7)
13635 CALL LINE("B",XX+11,YY+9,XX+15,YY+9)
13640 FOR I=0 TO 12 STEP 2:CALL LINE("B",XX+7+I,YY+1,XX+7+I,YY+2)
13642 NEXT I
13645 FOR I=0 TO 16 STEP 2:CALL PLOT("Y",XX+4+I,YY+14)
13650 CALL PLOT("Y",XX+4+I,YY+16):CALL PLOT("Y",XX+4+I,YY+18)
13655 NEXT I
13670 CALL LINE("Y",XX+7,YY+20,XX+17,YY+20)
13675 CALL LINE("R",XX+23,YY+17,XX+24,YY+17)
13690 RETURN
13700 REM --- NEC PC-8001 ---
13710 L=46:H=27:XX=XX-(L/2):YY=100-(H/2)
13720 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+10,42,15,"B")
13725 CALL RECT(XX+4,YY+13,28,9,"W"):CALL RECT(XX+35,YY+13,7,9,"W")
13730 CALL PLOT("R",XX+41,YY+11)
13735 FOR I=0 TO 10 STEP 2
13740 CALL LINE("B",XX+9+I,YY+2,XX+9+I,YY+4)
13745 CALL LINE("B",XX+25+I,YY+2,XX+25+I,YY+4)
13750 NEXT I
13755 CALL LINE("W",XX+8,YY+22,XX+26,YY+22)
13790 RETURN
13800 REM --- OSBORNE 1 ---
13810 L=40:H=31:XX=XX-(L/2):YY=100-(H/2)
13820 CALL RECT(XX,YY,L,H,"B"):CALL RECT(XX+1,YY+1,14,9,"x")
13835 CALL RECT(XX+25,YY+1,14,9,"x"):CALL RECT(XX+1,YY+1,14,9,"x")
13840 CALL RECT(XX+1,YY+11,14,3,"x"):CALL RECT(XX+25,YY+11,14,3,"x")
13845 CALL RECT(XX+16,YY+2,8,8,"G"):CALL RECT(XX+7,YY+4,2,3,"W")
13850 CALL RECT(XX+31,YY+4,2,3,"W"):CALL RECT(XX+4,YY+19,24,7,"W")
13855 CALL RECT(XX+31,YY+19,4,7,"W")
13860 CALL LINE("W",XX+8,YY+26,XX+22,YY+26)
13865 CALL LINE("W",XX,YY+18,XX,YY+22)
13870 CALL LINE("W",XX+39,YY+18,XX+39,YY+22)
13875 CALL LINE("W",XX+3,YY+5,XX+12,YY+5)
13880 CALL LINE("W",XX+27,YY+5,XX+36,YY+5)
13885 CALL LINE("W",XX,YY+15,XX+39,YY+15)
13887 CALL PLOT("R",XX+3,YY+7):CALL PLOT("R",XX+27,YY+7)
13890 RETURN
13900 REM --- THOMSON TO7 ---
13910 L=51:H=24:XX=XX-(L/2):YY=100-(H/2)
13920 CALL RECT(XX,YY+1,L,23,"w"):CALL RECT(XX+2,YY+7,47,3,"w")
13925 CALL RECT(XX+2,YY+11,11,11,"w"):CALL RECT(XX+14,YY+11,35,11,"B")
13930 CALL RECT(XX+4,YY+17,7,3,"B"):CALL KYB2(XX+16,YY+13,4,13,1,2,"W")
13935 CALL LINE("B",XX+2,YY+3,XX+48,YY+3)
13937 CALL LINE("B",XX+2,YY+5,XX+48,YY+5)
13940 FOR I=0 TO 8 STEP 2:CALL PLOT("B",XX+41+I,YY):NEXT I
13945 FOR I=0 TO 6 STEP 2:CALL PLOT("W",XX+44,YY+13+I)
13950 CALL PLOT("W",XX+46,YY+13+I):NEXT I
13955 CALL PLOT("W",XX+45,YY+17)
13960 CALL LINE("Y",XX+38,YY+17,XX+40,YY+17)
13990 RETURN
14000 REM --- ACORN ELECTRON ---
14010 L=40:H=21:XX=XX-(L/2):YY=100-(H/2)
14020 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+3,YY+1,34,5,"B")
14025 CALL RECT(XX+6,YY+8,28,9,"w"):CALL RECT(XX+12,YY+16,16,2,"B")
14030 CALL LINE("W",XX+13,YY+16,XX+26,YY+16)
14035 CALL LINE("B",XX+3,YY+6,XX+3,YY+19)
14040 CALL LINE("B",XX+36,YY+6,XX+36,YY+19)
14045 CALL LINE("W",XX+4,YY+2,XX+6,YY+2)
14050 CALL LINE("W",XX+10,YY+2,XX+13,YY+2)
14055 CALL LINE("G",XX+8,YY+2,XX+8,YY+1)
14060 CALL PLOT("R",XX+4,YY+9)
14090 RETURN
14100 REM --- MATRA ALICE ---
14110 L=23:H=22:XX=XX-(L/2):YY=100-(H/2)
14120 CALL RECT(XX,YY,L,H,"R"):CALL RECT(XX+1,YY+10,21,11,"B")
14125 CALL RECT(XX+19,YY+1,3,2,"W")
14130 CALL LINE("W",XX+9,YY+8,XX+13,YY+8)
14135 CALL LINE("W",XX+7,YY+19,XX+15,YY+19)
14140 CALL KYB2(XX+2,YY+11,4,10,0,2,"W")
14190 RETURN
14200 REM --- MSX ---
14210 L=44:H=23:XX=XX-(L/2):YY=100-(H/2)
14220 CALL RECT(XX,YY,L,H,"b"):CALL RECT(XX+2,YY+8,40,13,"B")
14225 CALL RECT(XX+3,YY+11,28,8,"W"):CALL RECT(XX+33,YY+11,8,8,"b")
14230 CALL RECT(XX+29,YY+3,13,2,"B")
14235 CALL LINE("W",XX+9,YY+19,XX+23,YY+19)
14240 CALL LINE("W",XX+33,YY+18,XX+40,YY+11)
14245 CALL LINE("W",XX+33,YY+11,XX+40,YY+18)
14250 CALL LINE("W",XX+33,YY+9,XX+40,YY+9)
14255 CALL LINE("B",XX+2,YY+2,XX+23,YY+2)
14260 CALL LINE("B",XX+2,YY+4,XX+23,YY+4)
14265 CALL LINE("B",XX+2,YY+6,XX+23,YY+6)
14270 CALL PLOT("R",XX+3,YY+9)
14290 RETURN
14300 REM --- APPLE LISA ---
14310 L=41:H=31:XX=XX-(L/2):YY=100-(H/2)
14320 CALL RECT(XX,YY,41,22,"w"):CALL RECT(XX,YY+24,41,7,"w")
14325 CALL RECT(XX+2,YY+23,27,5,"B"):CALL RECT(XX+32,YY+23,6,5,"B")
14330 CALL RECT(XX+35,YY+4,3,3,"B"):CALL RECT(XX+35,YY+13,3,3,"B")
14335 CALL RECT(XX+3,YY+3,20,16,"C"):CALL PLOT("W",XX+3,YY+3)
14340 CALL PLOT("W",XX+3,YY+18):CALL PLOT("W",XX+22,YY+18)
14345 CALL PLOT("W",XX+22,YY+3)
14350 CALL LINE("B",XX+25,YY+5,XX+34,YY+5)
14355 CALL LINE("B",XX+25,YY+14,XX+34,YY+14)
14390 RETURN
14400 REM --- NEC PC-9800 ---
14410 L=33:H=31:XX=XX-(L/2):YY=100-(H/2)
14420 CALL RECT(XX,YY,33,19,"w"):CALL RECT(XX,YY+20,33,11,"w")
14430 CALL RECT(XX+1,YY+22,31,7,"B"):CALL RECT(XX+3,YY+23,20,4,"W")
14435 CALL RECT(XX+26,YY+23,4,5,"W")
14440 CALL LINE("W",XX+7,YY+27,XX+18,YY+27)
14445 FOR I=0 TO 12 STEP 2:CALL LINE("B",XX+3,YY+3+I,XX+5,YY+3+I)
14450 CALL LINE("B",XX+28,YY+3+I,XX+30,YY+3+I):NEXT I
14490 RETURN
14500 REM --- APPLE MAC ---
14510 L=26:H=31:XX=XX-(L/2):YY=100-(H/2)
14515 CALL RECT(XX+3,YY,20,25,"w"):CALL RECT(XX+6,YY+3,14,11,"w")
14520 CALL RECT(XX+7,YY+4,12,9,"C"):CALL RECT(XX,YY+25,26,6,"w")
14525 CALL RECT(XX+2,YY+24,22,4,"B"):CALL RECT(XX+18,YY+18,2,2,"B")
14530 CALL PLOT("R",XX+5,YY+21):CALL PLOT("b",XX+6,YY+21)
14535 CALL PLOT("Y",XX+6,YY+20):CALL PLOT("G",XX+5,YY+20)
14540 CALL LINE("B",XX+12,YY+18,XX+17,YY+18)
14550 CALL RECT(XX+28,YY+28,5,3,"w")
14590 RETURN
14600 REM --- MO5 ---
14610 L=49:H=31:XX=XX-(L/2):YY=100-(H/2)
14620 CALL RECT(XX,YY,L,H,"B"):CALL RECT(XX+5,YY+1,8,5,"x")
14630 CALL KYB1(XX+2,YY+10,4,11,0,4,"W")
14632 CALL RECT(XX+17,YY+26,16,2,"W")
14635 CALL RECT(XX+2,YY+22,6,2,"Y")
14640 FOR I=0 TO 4 STEP 2:CALL LINE("W",XX+1,YY+1+I,XX+3,YY+1+I)
14645 CALL LINE("W",XX+14,YY+1+I,XX+47,YY+1+I):NEXT I
14650 CALL PLOT("W",XX,YY+30):CALL PLOT("W",XX+48,YY+30)
14690 RETURN
14700 REM --- TANDY 1000 ---
14710 L=42:H=31:XX=XX-(L/2):YY=100-(H/2)
14720 CALL RECT(XX,YY,42,12,"w"):CALL RECT(XX+2,YY+11,38,5,"w")
14725 CALL RECT(XX+25,YY+1,14,10,"B"):CALL RECT(XX+3,YY+2,11,2,"B")
14730 CALL RECT(XX+31,YY+7,2,3,"W"):CALL RECT(XX+31,YY+2,2,3,"W")
14735 CALL PLOT("R",XX+6,YY+13):CALL PLOT("B",XX+8,YY+13)
14740 CALL PLOT("B",XX+11,YY+13):CALL PLOT("B",XX+13,YY+13)
14745 CALL PLOT("R",XX+26,YY+1):CALL PLOT("R",XX+26,YY+6)
14750 CALL PLOT("W",XX,YY):CALL PLOT("W",XX+41,YY)
14752 CALL PLOT("W",XX,YY+11):CALL PLOT("W",XX+41,YY+11)
14754 CALL LINE("W",XX+26,YY+3,XX+37,YY+3)
14756 CALL LINE("W",XX+26,YY+8,XX+37,YY+8)
14758 FOR I=0 TO 18 STEP 2:CALL LINE("B",XX+18+I,YY+12,XX+18+I,YY+14)
14760 NEXT I
14762 CALL RECT(XX+3,YY+17,36,14,"w"):CALL RECT(XX+5,YY+21,32,7,"w")
14764 CALL LINE("B",XX+17,YY+19,XX+24,YY+19)
14766 CALL LINE("B",XX+30,YY+22,XX+30,YY+26)
14768 CALL LINE("W",XX+12,YY+27,XX+22,YY+27)
14770 CALL LINE("B",XX+11,YY+28,XX+23,YY+28)
14790 RETURN
14800 REM --- ATARI 520ST ---
14810 L=47:H=26:XX=XX-(L/2):YY=100-(H/2)
14815 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX,YY+7,47,5,"w")
14820 CALL RECT(XX+2,YY+13,29,10,"w"):CALL RECT(XX+32,YY+13,5,5,"w")
14825 CALL RECT(XX+38,YY+13,7,10,"w")
14830 CALL LINE("B",XX+3,YY+9,XX+33,YY+9)
14835 CALL LINE("b",XX+38,YY+9,XX+43,YY+9)
14840 FOR I=0 TO 30 STEP 3:CALL PLOT("B",XX+2+I,YY+10):NEXT I
14845 FOR I=0 TO 39 STEP 3
14850 CALL LINE("B",XX+1+I,YY+6,XX+6+I,YY+1):NEXT I
14855 CALL LINE("W",XX+8,YY+22,XX+23,YY+22)
14860 CALL LINE("B",XX+7,YY+23,XX+24,YY+23)
14890 RETURN
14900 REM --- EXL-100 ---
14910 L=53:H=28:XX=XX-(L/2):YY=100-(H/2)
14915 CALL RECT(XX,YY,53,11,"B"):CALL RECT(XX+30,YY+4,7,2,"W")
14920 CALL RECT(XX+39,YY+4,7,2,"W"):CALL PLOT("W",XX,YY)
14925 CALL PLOT("W",XX+52,YY):CALL PLOT("W",XX+52,YY+10)
14930 CALL PLOT("W",XX,YY+10):CALL PLOT("W",XX+30,YY+8)
14935 CALL PLOT("W",XX+32,YY+8):CALL PLOT("W",XX+34,YY+8)
14940 CALL PLOT("W",XX+36,YY+8)
14945 CALL LINE("W",XX+48,YY+3,XX+48,YY+6)
14950 CALL LINE("Y",XX+50,YY+3,XX+50,YY+6)
14951 FOR I=0 TO 8 STEP 2:CALL LINE("W",XX+2,YY+1+I,XX+27,YY+1+I)
14952 NEXT I
14955 CALL RECT(XX+8,YY+13,35,15,"B")
14960 CALL KYB2(XX+11,YY+17,4,13,0,2,"W")
14965 FOR I=0 TO 6 STEP 2
14970 CALL LINE("Y",XX+40,YY+17+I,XX+41,YY+17+I):NEXT I
14975 CALL LINE("W",XX+17,YY+25,XX+29,YY+25)
14990 RETURN
15000 REM --- VG-5000 ---
15010 L=38:H=26:XX=XX-(L/2):YY=100-(H/2)
15020 CALL RECT(XX,YY,L,H,"B"):CALL KYB2(XX+4,YY+14,4,11,0,2,"W")
15025 CALL LINE("W",XX+8,YY+22,XX+16,YY+22)
15030 FOR I=0 TO 4 STEP 2:CALL PLOT("W",XX+10+I,YY+7)
15035 CALL LINE("W",XX,YY+1+I,XX+37,YY+1+I)
15037 CALL PLOT("W",XX+30+I,YY+14):CALL PLOT("W",XX+30+I,YY+16)
15038 CALL PLOT("W",XX+30+I,YY+18):NEXT I
15040 CALL PLOT("W",XX+32,YY+20):CALL PLOT("W",XX+34,YY+20)
15042 CALL PLOT("W",XX+32,YY+22):CALL PLOT("W",XX+34,YY+22)
15044 CALL PLOT("R",XX+36,YY+11)
15046 CALL LINE("W",XX+8,YY,XX+8,YY+8):CALL LINE("W",XX+29,YY,XX+29,YY+8)
15048 CALL LINE("W",XX,YY+9,XX+37,YY+9)
15050 CALL LINE("Y",XX+4,YY+12,XX+7,YY+12)
15055 CALL LINE("Y",XX+32,YY+12,XX+34,YY+12)
15060 CALL LINE("Y",XX+22,YY+20,XX+24,YY+20)
15090 RETURN
15100 REM --- MITS ALTAIR ---
15110 L=45:H=24:XX=XX-(L/2):YY=100-(H/2)
15120 CALL RECT(XX,YY,L,H,"b"):CALL RECT(XX+1,YY+1,43,19,"B")
15125 CALL RECT(XX+1,YY+20,43,3,"W")
15130 FOR I=0 TO 14 STEP 2:CALL PLOT("R",XX+3+I,YY+4)
15132 CALL PLOT("R",XX+26+I,YY+4):CALL PLOT("R",XX+26+I,YY+8)
15134 CALL PLOT("R",XX+7+I,YY+8):CALL PLOT("W",XX+7+I,YY+13)
15136 CALL PLOT("W",XX+26+I,YY+13):NEXT I
15138 CALL PLOT("R",XX+24,YY+8):CALL PLOT("W",XX+24,YY+13)
15140 CALL PLOT("R",XX+2,YY+8):CALL PLOT("R",XX+4,YY+8)
15145 FOR I=0 TO 24 STEP 3:CALL PLOT("W",XX+3+I,YY+17)
15150 NEXT I
15155 CALL LINE("B",XX+5,YY+21,XX+9,YY+21)
15157 CALL LINE("B",XX+12,YY+21,XX+16,YY+21)
15158 CALL LINE("B",XX+19,YY+21,XX+23,YY+21)
15190 RETURN
15200 REM --- COMPUCOLOR II ---
15210 L=43:H=16:XX=XX-(L/2):YY=100-(H/2)
15220 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+7,YY+4,25,9,"B")
15225 CALL RECT(XX+2,YY+5,4,8,"B"):CALL RECT(XX+34,YY+5,7,2,"B")
15230 CALL RECT(XX+34,YY+3,7,2,"R"):CALL RECT(XX+36,YY+8,5,6,"B")
15235 CALL RECT(XX+34,YY+8,5,4,"G"):CALL RECT(XX+34,YY+12,2,2,"G")
15237 CALL RECT(XX+4,YY+5,2,2,"b"):CALL RECT(XX+2,YY+7,2,2,"R")
15239 CALL RECT(XX+4,YY+7,2,2,"M"):CALL RECT(XX+2,YY+9,2,2,"G")
15240 CALL RECT(XX+2,YY+11,2,2,"Y"):CALL RECT(XX+9,YY+7,2,2,"R")
15242 CALL RECT(XX+11,YY+7,2,2,"W"):CALL RECT(XX+11,YY+9,2,2,"Y")
15244 CALL RECT(XX+15,YY+7,2,2,"G"):CALL RECT(XX+17,YY+7,2,2,"b")
15246 CALL RECT(XX+21,YY+7,2,2,"M")
15248 CALL LINE("B",XX+12,YY+13,XX+26,YY+13)
15290 RETURN
15300 REM --- EXIDY SORCERER ---
15310 L=45:H=26:XX=XX-(L/2):YY=100-(H/2)
15315 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+11,41,13,"B")
15320 CALL RECT(XX+3,YY+14,32,7,"W"):CALL RECT(XX+36,YY+14,6,7,"W")
15325 CALL RECT(XX+35,YY+5,4,4,"B")
15330 CALL LINE("B",XX+4,YY+1,XX+18,YY+1)
15335 CALL LINE("B",XX+26,YY+1,XX+40,YY+1)
15340 CALL LINE("W",XX+12,YY+21,XX+24,YY+21)
15390 RETURN
15400 REM --- DAI ---
15410 L=27:H=31:XX=XX-(L/2):YY=100-(H/2)
15420 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+6,YY,15,6,"w")
15425 CALL RECT(XX+2,YY+21,23,8,"w"):CALL RECT(XX+3,YY+25,2,2,"b")
15430 CALL RECT(XX+22,YY+22,2,5,"b")
15435 CALL LINE("B",XX+3,YY+27,XX+7,YY+27)
15437 CALL LINE("B",XX+19,YY+27,XX+23,YY+27)
15439 CALL LINE("G",XX+2,YY+22,XX+2,YY+24)
15440 CALL PLOT("R",XX+23,YY+22)
15442 FOR I=0 TO 4 STEP 2:CALL PLOT("R",XX+3+I,YY+11)
15446 CALL PLOT("B",XX+3+I,YY+12):CALL PLOT("G",XX+3+I,YY+13)
15448 NEXT I
15450 FOR I=0 TO 12 STEP 2
15452 CALL LINE("B",XX+8+I,YY+1,XX+8+I,YY+4)
15454 NEXT I
15490 RETURN
15500 REM --- NEWBRAIN ---
15510 L=25:H=17:XX=XX-(L/2):YY=100-(H/2)
15520 CALL RECT(XX,YY+1,25,16,"w"):CALL RECT(XX+11,YY+3,12,3,"w")
15525 CALL KYB2(XX+3,YY+8,4,10,0,2,"B")
15527 CALL LINE("B",XX+9,YY+14,XX+15,YY+14)
15530 CALL LINE("B",XX+3,YY+5,XX+6,YY+5)
15535 CALL LINE("G",XX+12,YY+4,XX+21,YY+4)
15540 CALL LINE("B",XX+3,YY,XX+20,YY+0)
15590 RETURN
15600 REM --- DRAGON 32 ---
15610 L=24:H=31:XX=XX-(L/2):YY=100-(H/2)
15615 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+21,20,7,"B")
15620 CALL RECT(XX,YY+7,24,5,"w"):CALL RECT(XX+2,YY+13,11,3,"B")
15625 CALL LINE("B",XX+1,YY+9,XX+22,YY+9)
15630 CALL LINE("B",XX+7,YY+28,XX+16,YY+28)
15635 CALL PLOT("R",XX+3,YY+14):CALL PLOT("R",XX+7,YY+14)
15640 CALL PLOT("Y",XX+8,YY+14):CALL PLOT("G",XX+9,YY+14)
15645 CALL PLOT("b",XX+10,YY+14):CALL PLOT("W",XX+11,YY+14)
15650 FOR I=0 TO 6 STEP 2:CALL LINE("B",XX+I+3,YY+1,XX+I+3,YY+2)
15655 CALL LINE("B",XX+I+14,YY+1,XX+I+14,YY+2):NEXT I
15690 RETURN
15700 REM --- ENTERPRISE 64 ---
15710 L=45:H=27:XX=XX-(L/2):YY=100-(H/2)
15720 CALL RECT(XX,YY,45,25,"B"):CALL RECT(XX+4,YY+12,32,12,"x")
15725 CALL RECT(XX+35,YY+12,5,6,"x")
15727 CALL LINE("B",XX+45,YY+1,XX+45,YY+8)
15729 CALL LINE("W",XX+1,YY+9,XX+43,YY+9)
15730 CALL PLOT("R",XX+37,YY+7):CALL PLOT("Y",XX+38,YY+7)
15732 CALL PLOT("G",XX+39,YY+7):CALL PLOT("b",XX+40,YY+7)
15734 CALL PLOT("M",XX+41,YY+7):CALL RECT(XX+5,YY+13,30,2,"b")
15736 CALL RECT(XX+5,YY+15,2,8,"G"):CALL RECT(XX+33,YY+15,6,2,"G")
15738 CALL RECT(XX+35,YY+13,2,2,"G"):CALL RECT(XX+33,YY+17,2,6,"G")
15740 CALL RECT(XX+31,YY+21,2,2,"G"):CALL RECT(XX+39,YY+21,2,2,"G")
15741 CALL RECT(XX+37,YY+13,2,2,"R")
15742 CALL LINE("B",XX+12,YY+23,XX+26,YY+23)
15744 CALL LINE("W",XX+11,YY+24,XX+27,YY+24)
15746 CALL LINE("B",XX+1,YY+25,XX+43,YY+25)
15748 CALL LINE("B",XX+2,YY+26,XX+42,YY+26)
15750 FOR I=0 TO 8 STEP 2
15755 CALL LINE("W",XX+1+I,YY,XX+I+1,YY+1):NEXT I
15790 RETURN
15800 REM --- LASER 200 ---
15810 L=34:H=19:XX=XX-(L/2):YY=100-(H/2)
15815 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+7,30,10,"B")
15820 CALL RECT(XX+2,YY+2,8,2,"b"):CALL PLOT("R",XX+30,YY+8)
15825 CALL KYB2(XX+4,YY+8,4,13,0,2,"W")
15830 FOR I=0 TO 8 STEP 2
15835 CALL LINE("B",XX+21+I,YY+1,XX+21+I,YY+3):NEXT I
15890 RETURN
15900 REM --- INTERACT COMPUTER ---
15910 L=51:H=22:XX=XX-(L/2):YY=100-(H/2)
15920 CALL RECT(XX,YY,L,H,"B"):CALL RECT(XX+2,YY+6,33,14,"x")
15925 CALL RECT(XX+38,YY+1,11,6,"x"):CALL RECT(XX+38,YY+10,11,6,"R")
15927 CALL RECT(XX+39,YY+11,9,4,"B")
15930 CALL RECT(XX+40,YY+12,2,2,"W"):CALL RECT(XX+45,YY+12,2,2,"W")
15935 CALL RECT(XX+37,YY+19,13,4,"x")
15940 FOR I=0 TO 6 STEP 3
15945 CALL LINE("W",XX+40+I,YY+20,XX+40+I,YY+21):NEXT I
15950 CALL KYB2(XX+5,YY+8,5,14,1,2,"W"):CALL PLOT("R",XX+3,YY+4)
15955 CALL PLOT("R",XX+32,YY+4):CALL LINE("W",XX+5,YY+4,XX+8,YY+4)
15990 RETURN
16000 REM --- TOMY TUTOR ---
16010 L=38:H=27:XX=XX-(L/2):YY=100-(H/2)
16015 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+24,YY+3,11,3,"w")
16020 CALL RECT(XX+3,YY+10,32,14,"b"):CALL KYB2(XX+6,YY+12,4,9,0,3,"W")
16025 CALL LINE("M",XX+12,YY+21,XX+24,YY+21)
16030 CALL LINE("b",XX+3,YY+4,XX+7,YY+4)
16035 CALL PLOT("R",XX+34,YY+8)
16040 FOR I=0 TO 10 STEP 2:CALL PLOT("B",XX+3+I,YY+1)
16045 CALL PLOT("B",XX+24+I,YY+1):NEXT I
16090 RETURN
16100 REM --- LYNX ---
16110 L=39:H=22:XX=XX-(L/2):YY=100-(H/2)
16120 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+4,YY+9,31,9,"w")
16125 CALL RECT(XX+2,YY+4,8,3,"B"):CALL PLOT("W",XX+3,YY+5)
16130 CALL PLOT("R",XX+5,YY+5):CALL PLOT("Y",XX+6,YY+5)
16135 CALL PLOT("b",XX+7,YY+5):CALL PLOT("G",XX+8,YY+5)
16140 CALL LINE("W",XX+13,YY+17,XX+25,YY+17)
16145 CALL LINE("B",XX+12,YY+18,XX+26,YY+18)
16150 FOR I=0 TO 34 STEP 2
16155 CALL LINE("B",XX+2+I,YY+1,XX+2+I,YY+2):NEXT I
16190 RETURN
16200 REM --- SANYO PHC-25 ---
16210 L=36:H=19:XX=XX-(L/2):YY=100-(H/2)
16215 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+2,32,3,"B")
16220 CALL RECT(XX+2,YY+6,32,11,"B")
16225 CALL KYB2(XX+5,YY+7,4,13,0,2,"W")
16230 FOR I=0 TO 6 STEP 2:CALL PLOT("R",XX+3,YY+7+I)
16235 CALL PLOT("R",XX+31,YY+7+I):NEXT I
16240 FOR I=0 TO 12 STEP 2:CALL PLOT("R",XX+19+I,YY+3):NEXT I
16245 CALL LINE("W",XX+4,YY+3,XX+8,YY+3)
16247 CALL LINE("G",XX+13,YY+3,XX+14,YY+3)
16250 CALL PLOT("b",XX+15,YY+3)
16255 CALL LINE("W",XX+12,YY+15,XX+22,YY+15)
16290 RETURN
16300 REM --- SHARP MZ700 ---
16310 L=48:H=27:XX=XX-(L/2):YY=100-(H/2)
16320 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+2,YY+1,44,7,"B")
16325 CALL RECT(XX+2,YY+9,44,3,"B"):CALL RECT(XX+4,YY+15,31,8,"w")
16327 CALL RECT(XX+39,YY+16,3,7,"B"):CALL RECT(XX+37,YY+18,7,3,"B")
16329 CALL RECT(XX+12,YY+2,13,2,"W"):CALL RECT(XX+30,YY+1,11,4,"x")
16330 CALL RECT(XX+30,YY+6,11,2,"W")
16332 CALL LINE("W",XX+9,YY+1,XX+9,YY+7)
16334 CALL LINE("W",XX+27,YY+1,XX+27,YY+7)
16336 FOR I=0 TO 8 STEP 2:CALL PLOT("B",XX+31+I,YY+7)
16338 NEXT I
16340 CALL LINE("W",XX+3,YY+10,XX+8,YY+10)
16342 CALL LINE("W",XX+40,YY+10,XX+43,YY+10)
16344 CALL PLOT("R",XX+38,YY+10)
16346 CALL LINE("b",XX+4,YY+13,XX+18,YY+13)
16348 CALL LINE("Y",XX+37,YY+13,XX+44,YY+13)
16350 CALL LINE("Y",XX+40,YY+17,XX+40,YY+21)
16352 CALL LINE("Y",XX+38,YY+19,XX+42,YY+19)
16354 CALL LINE("W",XX+13,YY+22,XX+24,YY+22)
16356 CALL LINE("B",XX+12,YY+23,XX+25,YY+23)
16358 CALL RECT(XX+5,YY+16,3,6,"Y"):CALL RECT(XX+31,YY+16,3,6,"Y")
16390 RETURN
16400 REM --- APPLE IIGS ---
16410 L=27:H=30:XX=XX-(L/2):YY=100-(H/2)
16420 CALL RECT(XX+3,YY,21,18,"w"):CALL RECT(XX+6,YY+3,15,12,"C")
16422 CALL RECT(XX+4,YY+17,19,10,"w"):CALL RECT(XX,YY+26,27,4,"w")
16424 CALL RECT(XX+28,YY+27,5,3,"w"):CALL PLOT("G",XX+20,YY+16)
16426 CALL PLOT("G",XX+20,YY+25):CALL PLOT("G",XX+6,YY+20)
16428 CALL PLOT("Y",XX+7,YY+20):CALL PLOT("R",XX+6,YY+21)
16430 CALL PLOT("b",XX+7,YY+21)
16432 CALL LINE("B",XX+9,YY+21,XX+11,YY+21)
16434 CALL LINE("B",XX+5,YY+24,XX+21,YY+24)
16490 RETURN
16500 REM --- APPOLO SQUALE ---
16510 L=49:H=17:XX=XX-(L/2):YY=100-(H/2)
16515 CALL RECT(XX,YY,L,H,"w"):CALL RECT(XX+34,YY,9,17,"w")
16520 CALL RECT(XX+3,YY+3,23,10,"w"):CALL RECT(XX+39,YY+6,2,10,"B")
16522 CALL RECT(XX+4,YY+6,2,6,"B"):CALL RECT(XX+22,YY+5,3,2,"B")
16524 CALL RECT(XX+23,YY+10,2,2,"B"):CALL RECT(XX+29,YY+10,2,4,"B")
16526 CALL RECT(XX+28,YY+11,4,2,"B"):CALL RECT(XX+29,YY+4,2,2,"b")
16528 CALL LINE("W",XX+9,YY+12,XX+18,YY+12)
16530 CALL LINE("B",XX+8,YY+13,XX+19,YY+13)
16532 CALL LINE("B",XX+35,YY+4,XX+41,YY+4)
16534 FOR I=0 TO 6 STEP 2
16536 CALL LINE("B",XX+44,YY+3+I,XX+47,YY+3+I)
16538 NEXT I
16540 CALL PLOT("R",XX+36,YY+14)
16590 RETURN
19999 REM --- FUNCTIONS ---
20000 SUB RECT(X,Y,L,H,C$)
20005 L=L-1
20010 IF C$="w" OR C$="x" THEN GOTO 20055
20020 FOR I=0 TO H-1
20030 CALL LINE(C$,X,Y+I,X+L,Y+I)
20040 NEXT I
20050 SUBEXIT
20055 H=H-1
20057 IF C$="w" THEN C$="B" ELSE C$="W"
20060 CALL LINE(C$,X,Y,X+L,Y)
20070 CALL LINE(C$,X+L,Y,X+L,Y+H)
20080 CALL LINE(C$,X+L,Y+H,X,Y+H)
20090 CALL LINE(C$,X,Y+H,X,Y)
20100 SUBEND
20200 REM --- KEYBOARD1 ---
20210 SUB KYB1(X,Y,R,C,O,E,C$)
20220 FOR I=1 TO R
20225 W=Y+E*(I-1)
20230 FOR J=1 TO C
20235 Z=X+E*(J-1)
20240 CALL LINE(C$,Z,W,Z+1,W)
20250 CALL LINE(C$,Z,W+1,Z+1,W+1)
20260 NEXT J
20270 X=X+1:IF I=3 THEN X=X-(E-1)
20280 NEXT I
20290 IF O=1 THEN CALL LINE(C$,X+(3*E),W,X+(6*E),W)
20300 IF O=1 THEN CALL LINE(C$,X+(3*E),W+1,X+(6*E),W+1)
20310 SUBEND
20400 REM --- KEYBOARD2 ---
20410 SUB KYB2(X,Y,R,C,O,E,C$)
20420 FOR I=1 TO R
20430 W=Y+E*(I-1)
20440 FOR J=1 TO C
20450 Z=X+E*(J-1)
20460 CALL PLOT(C$,Z,W)
20470 NEXT J:NEXT I
20480 IF O=1 THEN CALL LINE(C$,X+(3*E),W,X+(8*E),W)
20490 SUBEND